Aeon Timeline import/export

[mwra (Mark Anderson)]

Nice. One of the issues I’ve been thinking on is how, especially if new to export and the app—to deal with formatting of various data types. I now realise aTbRef lacks a full list telling you what you get, by default using ^value()^. It is covered in part here, but there have been newer data types the since article was first written. The article’s ‘last edited’ date of today is just me fixing a (now obvious) typo, but—note to self—that page needs a review.

Anyway, that reflection suggests to me that it might be useful to make a collection of per-data-type sub-routines for ‘default’ transforms of exported defaults.

Nonetheless, thanks for sharing. I shall enjoy looking through that in slow time.

It also makes me think it might be using to have a demo sub-forum for AppleScripts as, even if the task is not related to the user’s current task, scripts can provide valuable general syntax ideas for others.

[tarkine (John Perry)]

@sumnerg

# Places quoted character-separated values (CSV) on clipboard for pasting wherever.
# v. 1.2 -- includes simple date conversion and "edit the box" dialog

property entryString : "Name Text NoteURL t"

set dialogText to "Export selected notes from Tinderbox to the system clipboard in a csv (character-separated value) format for pasting into spreadsheets or other applications." & return & return & "1. Select notes in Tinderbox. Non-contiguous multi levels ok." & return & return & "2. Edit the box below to choose Tinderbox attributes in the order that you want them to appear in the spreadsheet. Spell their names exactly. Add/delete/reorder as needed. Use one or more spaces between names." & return & return & "3. After the last attribute name enter one or more spaces followed by the delimiter to be used to separate items in the exported csv." & return & return & "4. Click 'Continue' to export to the clipboard for pasting. " & return & return & "                  ------------------------" & return & return & "For the delimiter enter a single character:" & return & return & "   t  for tab" & return & "   ,  for comma" & return & "   ;  for semicolon" & return & "   |  for pipe" & return & "           and so on..." & return & return & "Examples of valid entries in the box:" & return & return & "   Name MyString Path Text ," & return & "   Name MyString MyDate MySet Text ;" & return & "   Name  Text MySet MyString MyDate   ;" & return & "   Name   Text   MyString   NoteURL       t" & return

set theResponse to display dialog dialogText default answer entryString buttons {"Cancel", "Continue"} default button "Continue" with title "Tinderbox Export to Spreadsheet"

set entryString to trimRight(text returned of theResponse)

tell entryString
	if character -2 is not " " then error "Can't find a delimiter at end."
	set myDelimiter to last character
	if myDelimiter is "t" then set myDelimiter to tab
	set grabAttribs to words of text 1 thru -2 --if "t" present ignore as last "word"
end tell

--  NO USER TINKERING NEEDED BELOW THIS LINE, at least in theory;)

set text item delimiters to quote & myDelimiter & quote

# create separate list to hold lists of attribute values (a "list of lists")
copy grabAttribs to attribVals

set numCols to grabAttribs's length

tell application "Tinderbox 9"
	tell front document's selections -- (note use of plural)
		repeat with i from 1 to numCols
			set attrName to grabAttribs's item i
			tell attribute attrName
				# add list of this attribute's values to the list of lists
				set attribVals's item i to value
				# if attribute is date then convert format
				if item 1's type is "date" then copy my convertDates(attribVals's item i) to attribVals's item i
			end tell
			# adds list of this attribute's values to the list of lists
		end repeat
	end tell
end tell

set numRows to attribVals's item 1's length

set outStr to quote & (grabAttribs as string) & quote & return # header row

repeat with i from 1 to numRows
	set rowItems to {}
	repeat with j from 1 to numCols
		set rowItems's end to attribVals's item j's item i
	end repeat
	set outStr to outStr & quote & (rowItems as string) & quote & return # body row
end repeat

set the clipboard to outStr

display notification "Tinderbox data ready for pasting."

--return outStr -- uncomment this line to view output in Script Editor 'Result' pane

#### handlers (similar to subroutines or functions in other languages) ####

to convertDates(listOfIsoDates)
	-- convert list of Tinderbox ISO 8601 dates to spaced date-time string for spreadsheets
	set convertedDates to {}
	repeat with i from 1 to listOfIsoDates's length
		tell listOfIsoDates's item i
			if it is "never" then
				set convertedDates's end to ""
			else
				set convertedDates's end to its text 1 thru 10 & " " & text 12 thru 19
			end if
		end tell
	end repeat
	return convertedDates
end convertDates

to trimRight(someText)
	-- removes any spaces at end of a string
	repeat until someText does not end with " "
		set someText to text 1 thru -2 of someText
	end repeat
	return someText
end trimRight

Slick. Pasted results into Numbers, exported as a .csv and imported that into AT2 and the results displayed as expected. Many thanks, lots of time saved.

[tarkine (John Perry)]

@sumnerg

AppleScript below, which requires no setup of export templates, etc. Nor does it require AppleScript

Happily endorse the ideas of aTbRef having a full list telling you what you get, especially in the context of enabling the user to tell the app what the user wants (to the extent this is practicable) and making a collection of per-data-type sub-routines for ‘default’ transforms of exported defaults. As sumnerg said, the script approach is portable across Tinderbox documents so it doesn’t have to be recreated or copied each time another Tinderbox document is used. Important point to justify making the per-data-type sub-routines.

[mwra (Mark Anderson)]

@tarkine

aTbRef having a full list telling you what you get

Indeed, I just have to carve out some time for testing. Testing trumps assumption/memory every time. the writing up takes less time. But, it’s on my to-do list for aTbRef9.

[mwra (Mark Anderson)]

I’ve added a new aTbRef note, here, that mentions transform—if any—made by ^value()^ when exporting different data types.